Flix (programming language)

Flix is a programming language in the ML-family of languages. Its type and effect system is based on Hindley-Milner with several extensions, including row polymorphism and Boolean unification. The syntax of Flix is inspired by Scala and uses short keywords and curly braces. Flix supports uniform function call syntax which allows a function call f(x, y, z) to be written as x.f(y, z). The concurrency model of Flix is inspired by Go and based on channels and processes. A process is a light-weight thread that does not share (mutable) memory with another process. Processes communicate over channels which are bounded or unbounded queues of immutable messages.

While many programming languages support a mixture of functional and imperative programming, the Flix type and effect system tracks the purity of every expression making it possible to write parts of a Flix program in a purely functional style with purity enforced by the effect system.

Flix programs compile to JVM bytecode and are executable on the Java Virtual Machine (JVM).{{cite book |last1=Yee |first1=Ming-Ho |title=Implementing a Functional Language for Flix |date=2016-09-15 |publisher=University of Waterloo}}

The Flix compiler performs whole program compilation, eliminates polymorphism via monomorphization,{{cite web |title=Monomorphise |url=http://mlton.org/Monomorphise |website=mlton.org}} and uses tree shaking to remove unreachable code.

Monomorphization avoids boxing of primitive values at the cost of longer compilation times and larger executable binaries. Flix has some support for interoperability with programs written in Java.{{cite web |title=Programming Flix - Interoperability |url=https://doc.flix.dev/interoperability/ |website=flix.dev}}

Flix supports tail call elimination which ensures that function calls in tail position never consume stack space and hence cannot cause the call stack to overflow.{{cite book |last1=Madsen |first1=Magnus |last2=Zarifi |first2=Ramin |last3=Lhoták |first3=Ondřej |title=Proceedings of the 27th International Conference on Compiler Construction |chapter=Tail call elimination and data representation for functional languages on the Java virtual machine |date=2018 |pages=139–150 |doi=10.1145/3178372.3179499|isbn=9781450356442 |s2cid=3432962 }} Since the JVM instruction set lacks explicit support for tail calls, such calls are emulated using a form of reusable stack frames.{{cite book |last1=Tauber |first1=Tomáš |last2=Bi |first2=Xuan |last3=Shi |first3=Zhiyuan |last4=Zhang |first4=Weixin |last5=Li |first5=Huang |last6=Zhang |first6=Zhenrui |last7=Oliveira |first7=Bruno C. D. S. |chapter=Memory-Efficient Tail Calls in the JVM with Imperative Functional Objects |title=Programming Languages and Systems |series=Lecture Notes in Computer Science |date=2015 |volume=9458 |pages=11–28 |doi=10.1007/978-3-319-26529-2_2|isbn=978-3-319-26528-5 }} Support for tail call elimination is important since all iteration in Flix is expressed through recursion.

The Flix compiler disallows most forms of unused or redundant code, including: unused local variables, unused functions, unused formal parameters, unused type parameters, and unused type declarations, such unused constructs are reported as compiler errors.{{cite web |title=Redundancies as Compile-Time Errors |url=https://flix.dev/blog/redundancies-as-compile-time-errors/ |website=flix.dev}} Variable shadowing is also disallowed. The stated rationale is that unused or redundant code is often correlated with erroneous code{{cite journal |last1=Engler |first1=D. |title=Using redundancies to find errors |journal=IEEE Transactions on Software Engineering |date=October 2003 |volume=29 |issue=10 |pages=915–928 |doi=10.1109/TSE.2003.1237172}}

A Visual Studio Code extension for Flix is available.{{cite web |title=flix - Visual Studio Marketplace |url=https://marketplace.visualstudio.com/items?itemName=flix.flix |website=marketplace.visualstudio.com |language=en-us}} The extension is based on the Language Server Protocol, a common interface between IDEs and compilers being developed by Microsoft.

Flix is open source software available under the Apache 2.0 License.

The following program prints "Hello World!" when compiled and executed:

def main(): Unit \ IO =

println("Hello World!")

The type and effect signature of the main function specifies that it has no parameters, returns a value of type Unit, and that the function has the IO effect, i.e. is impure. The main function is impure because it invokes printLine which is impure.

The following program fragment declares an algebraic data type (ADT) named Shape:

enum Shape {

case Circle(Int32), // has circle radius

case Square(Int32), // has side length

case Rectangle(Int32, Int32) // has height and width

}

The ADT has three constructors: Circle, Square, and Rectangle.

The following program fragment uses pattern matching to destruct a Shape value:

def area(s: Shape): Int32 = match s {

case Circle(r) => 3 * (r * r)

case Square(w) => w * w

case Rectangle(h, w) => h * w

}

The following program fragment defines a higher-order function named twice that when given a function f from Int to Int returns a function that applies f to its input two times:

def twice(f: Int32 -> Int32): Int32 -> Int32 = x -> f(f(x))

We can use the function twice as follows:

twice(x -> x + 1)(0)

Here the call to twice(x -> x + 1) returns a function that will increment its argument two times. Thus the result of the whole expression is 0 + 1 + 1 = 2.

The following program fragment illustrates a polymorphic function that maps a function f: a -> b over a list of elements of type a returning a list of elements of type b:

def map(f: a -> b, l: List[a]): List[b] = match l {

case Nil => Nil

case x :: xs => f(x) :: map(f, xs)

}

The map function recursively traverses the list l and applies f to each element constructing a new list.

Flix supports type parameter elision hence it is not required that the type parameters a and b are explicitly introduced.

The following program fragment shows how to construct a record with two fields x and y:

def point2d(): {x: Int32, y: Int32} = {x = 1, y = 2}

Flix uses row polymorphism to type records. The sum function below takes a record that has x and y fields (and possibly other fields) and returns the sum of the two fields:

def sum(r: {x: Int32, y: Int32 | rest}): Int = r.x + r.y

The following are all valid calls to the sum function:

sum({x = 1, y = 2})

sum({y = 2, x = 1})

sum({x = 1, y = 2, z = 3})

The Flix type and effect system separates pure and impure expressions.{{cite web |title=Programming Flix - Effects |url=https://doc.flix.dev/effects/ |website=flix.dev}}{{cite web|title=Rust Internals - Flix Polymorphic Effects|date=15 November 2020 |url=https://internals.rust-lang.org/t/flix-polymorphic-effects/13395}} A pure expression is guaranteed to be referentially transparent. A pure function always returns the same value when given the same argument(s) and cannot have any (observable) side-effects.

For example, the following expression is of type Int32 and has the empty effect set {}, i.e. it is pure:

1 + 2 : Int32 \ {}

whereas the following expression has the IO effect, i.e. is impure:

println("Hello World") : Unit \ IO

A higher-order function can specify that a function argument must be pure, impure, or that it is effect polymorphic.

For example, the definition of Set.exists requires that its function argument f is pure:

// The syntax a -> Bool is short-hand for a -> Bool \ {}

def exists(f: a -> Bool, xs: Set[a]): Bool = ...

The requirement that f must be pure ensures that implementation details do not leak. For example, since f is pure it cannot be used to determine in what order the elements of the set are traversed. If f was impure such details could leak, e.g. by passing a function that also prints the current element, revealing the internal element order inside the set.

A higher-order function can also require that a function is impure.

For example, the definition of List.foreach requires that its function argument f is impure:

def foreach(f: a -> Unit \ IO, xs: List[a]): Unit \ IO

The requirement that f must be impure ensures that the code makes sense: It would be meaningless to call List.foreach with a pure function since it always returns Unit.

The type and effect is sound, but not complete. That is, if a function is pure then it cannot cause an effect, whereas if a function is impure then it may, but not necessarily, cause an effect. For example, the following expression is impure even though it cannot produce an effect at run-time:

if (1 == 2) println("Hello World!") else ()

A higher-order function can also be effect polymorphic: its effect(s) can depend on its argument(s).

For example, the standard library definition of List.map is effect polymorphic:{{cite web |title=The Flix API - List|url=https://api.flix.dev/List |website=api.flix.dev}}

def map(f: a -> b \ e, xs: List[a]): List[b] \ e

The List.map function takes a function f from elements of type a to b with effect e. The effect of the map function is itself e. Consequently, if List.map is invoked with a pure function then the entire expression is pure whereas if it is invoked with an impure function then the entire expression is impure. It is effect polymorphic.

A higher-order function that takes multiple function arguments may combine their effects.

For example, the standard library definition of forward function composition >> is pure if both its function arguments are pure:{{cite web |title=The Flix API - Prelude |url=https://api.flix.dev/ |website=api.flix.dev}}

def >>(f: a -> b \ e1, g: b -> c \ e2): a -> c \ e1 + e2 = x -> g(f(x))

The type and effect signature can be understood as follows: The >> function takes two function arguments: f with effect e1 and g with effect e2. The effect of >> is effect polymorphic in the conjunction of e1 and e2. If both are pure then the overall expression is pure.

The type and effect system allows arbitrary set expressions to control the purity of function arguments.

For example, it is possible to express a higher-order function h that accepts two function arguments f and g where the effects of f are disjoint from those of g:

def h(f: a -> b \ e1, g: b -> c \ e2 - e1): Unit

If h is called with a function argument f which has the IO effect then g cannot have the IO effect.

The type and effect system can be used to ensure that statement expressions are useful, i.e. that if an expression or function is evaluated and its result is discarded then it must have a side-effect. For example, compiling the program fragment below:

def main(): Unit \ IO =

List.map(x -> 2 * x, 1 :: 2 :: Nil);

println("Hello World")

causes a compiler error:

-- Redundancy Error --------------------------------------------------

>> Useless expression: It has no side-effect(s) and its result is discarded.

2 | List.map(x -> 2 * x, 1 :: 2 :: Nil);

^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

useless expression.

because it is non-sensical to evaluate the pure expression List.map(x -> 2 * x, 1 :: 2 :: Nil) and then to discard its result. Most likely the programmer wanted to use the result (or alternatively the expression is redundant and could be deleted). Consequently, Flix rejects such programs.

Flix supports Datalog programs as first-class values.{{cite journal |last1=Arntzenius |first1=Michael |last2=Krishnaswami |first2=Neel |title=Seminaïve evaluation for a higher-order functional language |journal=Proceedings of the ACM on Programming Languages |date=January 2020 |volume=4 |issue=POPL |pages=1–28 |doi=10.1145/3371090|s2cid=208305062 |doi-access=free }} A Datalog program is a logic program that consists of a collection of unordered facts and rules. Together, the facts and rules imply a minimal model, a unique solution to any Datalog program. In Flix, Datalog program values can be passed to and returned from functions, stored in data structures, composed with other Datalog program values, and solved. The solution to a Datalog program (the minimal model) is itself a Datalog program. Thus, it is possible to construct pipelines of Datalog programs where the solution, i.e. "output", of one Datalog program becomes the "input" to another Datalog program.

The following edge facts define a graph:

Edge(1, 2). Edge(2, 3). Edge(3, 4).

The following Datalog rules compute the transitive closure of the edge relation:

Path(x, y) :- Edge(x, y).

Path(x, z) :- Path(x, y), Edge(y, z).

The minimal model of the facts and rules is:

Edge(1, 2). Edge(2, 3). Edge(3, 4).

Path(1, 2). Path(2, 3). Path(3, 4).

Path(1, 3). Path(1, 4). Path(2, 4).

In Flix, Datalog programs are values. The above program can be embedded in Flix as follows:

def main(): #{Edge(Int32, Int32), Path(Int32, Int32)} =

let f = #{

Edge(1, 2). Edge(2, 3). Edge(3, 4).

};

let p = #{

Path(x, y) :- Edge(x, y).

Path(x, z) :- Path(x, y), Edge(y, z).

};

solve f <+> p

The local variable f holds a Datalog program value that consists of the edge facts. Similarly, the local variable p is a Datalog program value that consists of the two rules. The f <+> p expression computes the composition (i.e. union) of the two Datalog programs f and p. The solve expression computes the minimal model of the combined Datalog program, returning the edge and path facts shown above.

Since Datalog programs are first-class values, we can refactor the above program into several functions. For example:

def edges(): #{Edge(Int32, Int32), Path(Int32, Int32)} = #{

Edge(1, 2). Edge(2, 3). Edge(3, 4).

}

def closure(): #{Edge(Int32, Int32), Path(Int32, Int32)} = #{

Path(x, y) :- Edge(x, y).

Path(x, z) :- Path(x, y), Edge(y, z).

}

def run(): #{Edge(Int32, Int32), Path(Int32, Int32)} = solve edges() <+> closure()

The un-directed closure of the graph can be computed by adding the rule:

Path(x, y) :- Path(y, x).

We can modify the closure function to take a Boolean argument that determines whether we want to compute the directed or un-directed closure:

def closure(directed: Bool): #{Edge(Int32, Int32), Path(Int32, Int32)} =

let p1 = #{

Path(x, y) :- Edge(x, y).

Path(x, z) :- Path(x, y), Edge(y, z).

};

let p2 = #{

Path(y, x) :- Path(x, y).

};

if (directed) p1 else (p1 <+> p2)

The Flix type system ensures that Datalog program values are well-typed.

For example, the following program fragment does not type check:

let p1 = Edge(123, 456).;

let p2 = Edge("a", "b").;

p1 <+> p2;

because in p1 the type of the Edge predicate is Edge(Int32, Int32) whereas in p2 it has type Edge(String, String). The Flix compiler rejects such programs as ill-typed.

The Flix compiler ensures that every Datalog program value constructed at run-time is stratified. Stratification is important because it guarantees the existence of a unique minimal model in the presence of negation. Intuitively, a Datalog program is stratified if there is no recursion through negation,{{cite book |last1=Minker |first1=Jack |title=Foundations of deductive databases and logic programming |publisher=Morgan Kaufmann}} i.e. a predicate cannot depend negatively on itself. Given a Datalog program, a cycle detection algorithm can be used to determine if it is stratified.

For example, the following Flix program contains an expression that cannot be stratified:

def main(): #{Male(String), Husband(String), Bachelor(String)} =

let p1 = Husband(x) :- Male(x), not Bachelor(x).;

let p2 = Bachelor(x) :- Male(x), not Husband(x).;

p1 <+> p2 // illegal, not stratified.

because the last expression constructs a Datalog program value whose precedence graph contains a negative cycle: the Bachelor predicate negatively depends on the Husband predicate which in turn (positively) depends on the Bachelor predicate.

The Flix compiler computes the precedence graph for every Datalog program valued expression and determines its stratification at compile-time. If an expression is not stratified, the program is rejected by the compiler.

The stratification is sound, but conservative. For example, the following program is unfairly rejected:

def main(): #{A(Int32), B(Int32)} =

if (true)

A(x) :- A(x), not B(x).

else

B(x) :- B(x), not A(x).

The type system conservatively assumes that both branches of the if expression can be taken and consequently infers that there may be a negative cycle between the A and B predicates. Thus the program is rejected. This is despite the fact that at run-time the main function always returns a stratified Datalog program value.

Flix is designed around a collection of stated principles:{{cite web |title=The Flix Programming Language - Principles |url=https://flix.dev/principles/ |website=flix.dev |accessdate=28 August 2020}}

• Everything is an expression. Most Flix constructs, except for top-level declarations, are expressions that evaluate to values.
• Closed-world assumption. The Flix compiler assumes that the source code of the entire program is available at compile-time.
• Pure and impure code is separated. The type and effect system precisely captures whether an expression may produce an effect{{cite web |title=Taming Impurity with Polymorphic Effects |url=https://flix.dev/blog/taming-impurity-with-polymorphic-effects/ |website=flix.dev}}
• The language has no compile-time warnings, only errors.

The principles also list several programming language features that have been deliberately omitted. In particular, Flix lacks support for:

• Null values. Instead the use of the Option data type is recommended.
• Implicit coercions. Instead type conversions must be performed explicitly by the programmer.
• Reflection. The programmer cannot reflect over the structure of the program at run-time.

{{reflist}}

• [https://flix.dev/ Official website]
• [https://github.com/flix/flix Flix implementation source code], hosted at GitHub.

Category:Procedural programming languages

Category:Functional languages

Category:Logic programming languages

Category:High-level programming languages