Integer BASIC

As a senior in high school, Steve Wozniak's electronics teacher arranged for the leading students in the class to have placements at local electronics companies. Wozniak was sent to Sylvania where he programmed in FORTRAN on an IBM 1130.{{cite interview |first=Allan |last=Baum | interviewer=David Brock |date=18 July 2016 |title=Oral History of Allen Baum |page=12}} That same year, General Electric placed a terminal in the high school that was connected to one of their mainframes running their time-sharing BASIC service, which they were heavily promoting at the time. After being given three days of access, the students were asked to write letters on why the school should receive a terminal permanently, but their efforts were ultimately unsuccessful.{{sfn|Wozniak|2014}}

Some years later, Wozniak was working at Hewlett-Packard (HP) running simulations of chip designs and logic layout for calculators.{{sfn|Wozniak|2014}} HP made major inroads in the minicomputer market with their HP 2000 series machines running a custom timesharing version of BASIC. For approximately {{US$|long=no|100000}}, one could build up a reasonably equipped machine that could support between 16 and 32 users running BASIC programs.{{Cite magazine |url=http://hpmemoryproject.org/news/tenyears_comp/measure_page_00.htm |title= Passing the 10-year mark |magazine= MEASURE Magazine |date= October 1976 |publisher= Hewlett Packard}} While expensive, it was still a fraction of the cost of the mainframe machines{{efn|An IBM 370/155 cost over {{US$|long=no|2 million}} in 1970 ({{Inflation|US|2000000|1970|fmt=eq|r=-6}}).{{cite web |url=https://www.arnnet.com.au/slideshow/541873/pictures-mostly-cool-history-ibm-mainframe/ |title=The (mostly) cool history of the IBM mainframe |first=Michael |last=Cooney |website=ARN}}}} and, for heavy users, less than the timesharing services.{{efn|Tymshare charged about {{US$|long=no|10}} per hour ({{Inflation|US|10|1970|fmt=eq}}) for accessing their systems,{{cite book |title=A History of Online Information Services, 1963–1976 |first1= Charles |last1=Bourne |first2=Trudi Bellardo |last2=Hahn |page=387 |url=https://books.google.com/books?id=LTTvmUU8rskC&pg=PA387|isbn= 9780262261753 |date= August 2003 |publisher= MIT Press }} while smaller services could be found for about {{US$|long=no|5}}.{{cite magazine |magazine=InfoWorld |date=27 April 1981 |url=https://books.google.com/books?id=DT4EAAAAMBAJ&pg=PA7 |title=Back to BASIC |first=Tim |last=Barry |page=7}}}} HP followed this with the HP 9830, a desktop-sized machine for {{US$|10000|1970|round=-3}} that also ran BASIC, which Wozniak had access to.{{sfn|Williams|Moore|1984|p=A71}}

{{Quote box |width=300px |quote=I sniffed the wind and knew that the key to making my computer good (popular) was to include a high-level language and that it had to be BASIC. |author=Steve Wozniak{{sfn|Wozniak|2014}}}}

In January 1975 the Altair 8800 was announced and sparked off the microcomputer revolution. In March, Wozniak attended the first meeting of the Homebrew Computer Club and began formulating the design of his own computer. One of the most important pieces of software for the Altair, and one of the most heavily pirated, was Altair BASIC from the recently formed Microsoft.{{cite book |title= Understanding Online Piracy |first= Nathan |last=Fisk |page=14 |publisher= ABC-CLIO |date= 2009 |isbn= 9780313354748 |url=https://books.google.com/books?id=ZZJxDwAAQBAJ&pg=PA14}} Wozniak concluded that his machine would have to have a BASIC of its own, which would, hopefully, be the first for the MOS Technology 6502 processor. As the language needed 4 KB RAM, he made that the minimum memory for the design.{{sfn|Wozniak|2014}}

Wozniak's references for BASIC were a copy of 101 BASIC Computer Games and an HP BASIC manual.{{sfn|Wozniak|2014}} He did not know that HP's BASIC was very different from the DEC BASIC variety used in 101 Games, which was also the basis of Microsoft BASIC for the Altair. Based on these sources, Wozniak began sketching out a syntax chart for the language. The design initially included floating-point support, but still hoping he might publish the first BASIC on the 6502 and become "a star", he decided to abandon floating-point and write a separate integer math system to save a few weeks programming time.{{sfn|Wozniak|2014}}

Wozniak would later describe his language as "intended primarily for games and educational uses".{{sfn|Wozniak|1977}} Referring to it throughout development as "GAME BASIC", Wozniak wrote the code by hand, translating the assembler code instructions into their machine code equivalents and then uploading the result to his computer.{{sfn|Weyhrich|2001|loc=The [Integer] BASIC, which we shipped with the first Apple II's, was never assembled — ever. There was one handwritten copy, all handwritten, all hand-assembled.}} Without any training on how to write a computer language, he used his HP calculator experience to implement a stack machine to interpret expressions. Once the basic routines were up and running, he worked on the other commands one-by-one in a modular fashion. With every visit to the Homebrew club, he demonstrated a few more features added in the last month.{{sfn|Wozniak|2014}}

{{Quote box |width=300px |quote=It was the most satisfying day of my life... I demonstrated Breakout [at Homebrew]-totally written in BASIC... After designing hardware arcade games, I knew that being able to program them in BASIC was going to change the world. |author=Steve Wozniak{{sfn|Williams|Moore|1984|p=A71}}}}

File:Apple 1 Advertisement Oct 1976.jpg

In early 1976 ads for its Apple I computer, Apple Inc made the claims that "our philosophy is to provide software for our machines free or at minimal cost"{{cite web|url=http://apple1.chez.com/Apple1project/Gallery/Gallery.htm|title=The Apple 1 Project}} and "yes folks, Apple BASIC is Free".{{cite web|url=http://www.gadgetspage.com/comps-peripheral/apple-i-computer-ad.html|title=Apple I Computer Ad|date=30 November 2009 }} This was printed shortly after Bill Gates's infamous Open Letter to Hobbyists that suggested that people were robbing him by copying versions of Altair BASIC.{{cite journal|title=Across the Editor's Desk |journal=Computer Notes |last=Bunnell |first=David |volume=1 |issue=4 |page=2 |publisher=MITS |location=Albuquerque NM. |date=September 1975 |url=http://startup.nmnaturalhistory.org/gallery/notesViewer.php?ii=75_9&p=2 |url-status=dead |archive-url=https://web.archive.org/web/20120323162008/http://startup.nmnaturalhistory.org/gallery/notesViewer.php?ii=75_9&p=2 |archive-date=March 23, 2012 }}

Wozniak had helped Steve Jobs, who worked for Atari, with a redesign of Breakout.{{cite web|url=http://classicgaming.gamespy.com/View.php?view=Articles.Detail&id=395|title=Classic Gaming: A Complete History of Breakout|publisher=GameSpy|access-date=April 19, 2010|archive-url= https://web.archive.org/web/20130813113450/http://classicgaming.gamespy.com/View.php?view=Articles.Detail&id=395|archive-date=August 13, 2013}} At some later point, he decided to see whether one could write the game in BASIC. He added commands to read paddle controllers and over a series of quick edits had a version of the game up and running. To improve its playability, he added a speaker to make clicks when the ball hit things. While showing it to Jobs, Wozniak demonstrated that he could quickly change the colors that his game used, just by altering the source code. Wozniak later wrote that he had proved that "software was much more flexible than hardware", and that he and Jobs realized that "now, anyone could create arcade games without having to design it in hardware."{{sfn|Wozniak|2014}}

Wozniak did complete a floating-point library for the 6502 and published it in the August 1976 edition of Dr. Dobb's Journal.{{cite magazine |url=https://archive.org/details/dr_dobbs_journal_vol_01/page/n207/mode/2up |first1=Roy |last1=Raskin |first2=Steven |last2=Wozniak |title=Floating Point Routines for the 6502 |magazine=Dr. Dobb's |date=August 1976 |pages=17–19}} This library was later made part of the ROMs for the Apple II.{{cite book |title= Apple II Reference Manual |date= January 1978 |publisher=Apple Computer |pages=94–95}} Wozniak began work on back-porting the floating-point code into Apple BASIC, but got sidetracked in the task of designing a floppy disk controller for what became the Disk II. Mike Markkula said the company would go to the Consumer Electronics Show in Las Vegas if the disk system was ready in time, so Wozniak and Randy Wigginton worked on it non-stop through the 1977 holidays.{{sfn|Wozniak|2018}}

When he returned to the topic of floating-point in BASIC, Jobs complained it was taking too long. Without Wozniak being aware, the company had already arranged a license with Microsoft to receive their recently completed 6502 version of the Altair code. Examining the MS code, Wozniak decided that it was easier to add graphics support to their code than add floating-point his own BASIC, as the latter required hand-patching of the original machine code while MS's was written in assembler and more easily modified. The development of Apple's BASIC ended in favor of what became Applesoft BASIC. Wozniak later noted, "My biggest disappointment was going to the awful string functions like {{code|2=basic|LEFT$(VAR, 5)}} and {{code|2=basic|MID$(VAR2,5,3)}} instead of my own".{{sfn|Wozniak|2018}}{{efn|The string handling was not "his own", but the same system used by HP BASIC.}}

When the Apple II shipped in the summer of 1977, Integer BASIC was supplied in ROM, while Applesoft BASIC shipped on cassette. This changed with the introduction of the Apple II Plus in 1979, when Applesoft was put in the ROM.{{sfn|Hertzfeld|1985}}

Like most BASIC implementations of the era, Integer BASIC acted as both the language interpreter as well as the line editing environment. When BASIC was running, a {{code|>}} command prompt was displayed where the user could enter statements.{{sfn|Raskin|1978|p=11}}{{efn|To make it clear which BASIC was running, Applesoft used the {{code|]}} prompt.}} Unlike later home computer platforms, BASIC was not the default environment when the Apple II started, it normally started in the monitor. BASIC was started by pressing {{key press|Ctrl|B}}{{key press|Return}}.{{sfn|Raskin|1978|p=12}}

Statements that were entered with leading numbers are entered into the program storage for "deferred execution",{{sfn|Raskin|1978|p=46}} either as new lines or replacing any that might have had the same number previously.{{sfn|Raskin|1978|pp=49-55}} Statements that were entered without a line number were referred to as commands, and ran immediately.{{efn|In what MS referred to more descriptively as "immediate mode".}} Line numbers could be from 0 to 32767,{{sfn|Raskin|1978|p=48}}{{efn|Helmers says the lowest line number is 1.{{sfn|Helmers|1978|p=24}}}} and lines could contain up to 128 characters.{{sfn|Raskin|1978|p=118}}

Integer BASIC also included the {{code|AUTO}} command to automatically enter line numbers at a given starting number like {{code|AUTO 100}}, adding 10 to the last number with every new line. {{code|AUTO 300,5}} would begin numbering at line 300 by fives; 300, 305, etc. Automatic numbering was turned off by entering {{code|MAN}}.{{sfn|Raskin|1978|pp=65-67}}

One interesting feature of the editor was that a section of the screen could be set aside as the "window", where live updates took place. This was normally the entire screen, but it could be limited to a smaller area by {{code|POKE}}ing values into memory locations 32 through 35.{{sfn|Raskin|1978|p=124}} This feature could be used to create an editable text area while the rest of the screen was in graphics mode.{{sfn|Wozniak|1977|loc="This mixed mode provides a 40 by 40 color graphics grid plus four lines of scrolling text at the bottom of the screen."}}

As in most BASICs, programs were started with the {{code|RUN}} command, and as was common, could be directed at a particular line number like {{code|RUN 300}}.{{sfn|Raskin|1978|p=100}} Execution could be stopped at any time using {{key press|Ctrl|C}}{{sfn|Raskin|1978|p=15}} and then restarted with {{code|CON}}tinue, as opposed to the more typical {{code|CONT}}.{{sfn|Raskin|1978|p=52}}

For step-by-step execution, the {{code|TRACE}} instruction could be used at the command prompt or placed within the program itself. When it was turned on, line numbers were printed out for each line the program visited. The feature could be turned off again with {{code|NOTRACE}}.{{sfn|Raskin|1978|p=107}}

A somewhat unusual feature was the {{code|DSP}} (for "display") command. When encountered in a program, from that point on any changes to a variable's value would be displayed. For instance, {{code|DSP X}} would display the value of X every time it changed, along with the line number where the change occurred.{{sfn|Raskin|1978|pp=100,101}} As with TRACE, DSP was turned off with {{code|NODSP}}.{{sfn|Helmers|1978|p=24}}

Where Dartmouth BASIC and HP-BASIC limited variable names to at most two characters (either a single letter or a letter followed by one digit), and where MS-BASIC allowed a letter followed by an optional letter or digit (ignoring subsequent characters), Integer BASIC was unusual in supporting any length variable name (e.g., SUM, GAMEPOINTS, PLAYER2). The only caveat was that variable names could not contain reserved words; for example, THISCOLOR and COLORFUL were invalid variable names because they contained the keyword {{code|COLOR}}, a system command.{{sfn|Raskin|1978|p=38}} Additionally, lines were limited to 128 characters, so variable names could not exceed that length.{{sfn|Raskin|1978|p=118}}

Integer BASIC, as its name implies, uses integers as the basis for its math package. These were stored internally as a 16-bit number, little-endian (as is the 6502). This allowed a maximum value for any calculation between -32767 and 32767; although the format could also store the value -32768, BASIC could not display that number. Calculations that resulted in values outside that range produced a {{code|>32767 ERR}}.{{sfn|Raskin|1978|p=27}}

Infix operators included {{code|+}} (addition), {{code|-}} (subtraction), {{code|*}} (multiplication), {{code|/}} (division), MOD (remainder) and exponent using the {{code|^}} character. Binary operators included {{code|AND}}, {{code|OR}} and {{code|NOT}}. Binary comparisons included the standard set of {{code|{{=}}}}, {{code|>}}, {{code|<}}, {{code|>{{=}}}}, {{code|<{{=}}}}, {{code|<>}} and the HP-inspired {{code|#}}, which was equivalent to <>.{{sfn|Raskin|1978|p=61}}

Only single-dimension arrays were allowed, limited in size only by the available memory.{{sfn|Raskin|1978|p=94}} Mathematical functions were sparse; only {{code|ABS}} (absolute value), {{code|SGN}} (sign) and {{code|RND}} (random number) were supported.{{sfn|Raskin|1978|p=40,120}} In contrast to MS-derived versions, where the parameter was ignored and {{code|RND}} always returned a value 0..<1, Integer BASIC used the parameter; {{code|RND(6)}} returned an integer from 0 to 5.{{sfn|Raskin|1978|p=40}}

Integer BASIC's string handling was based on the system in HP BASIC. This treated string variables as arrays of characters which had to be {{code|DIM}}ed prior to use. This is similar to the model in C{{cite web |url=https://www.learn-c.org/en/Strings |title= Strings |website=learn-c.org}} or Fortran 77.{{cite web |first=Steve |last=Brooks |url=http://math.hawaii.edu/~dale/190/characters_formats.pdf |website=University of Hawaii |title=Characters & Strings in Fortran}} This is in contrast to MS-like BASICs where strings are an intrinsic variable-length type.{{cite book |url=https://www.masswerk.at/nowgobang/2020/commodore-basic-variables |title=C64 Programmer's Manual |publisher=Commodore |chapter=Integer, Floating Point and String Variables}} Before MS-derived BASICs became the de facto standard, this style was not uncommon; North Star BASIC{{cite book |title=North Star BASIC version 6 |url=http://itelsoft.com.au/north_star_manuals/North_Star_BASIC_Version_6.pdf |publisher=North Star Corporation |date=1977 |access-date=2020-03-03 |archive-date=2020-03-05 |archive-url=https://web.archive.org/web/20200305045335/https://itelsoft.com.au/north_star_manuals/North_Star_BASIC_Version_6.pdf |url-status=dead }} and Atari BASIC{{cite book |title=The ATARI BASIC Reference Manual |publisher=Atari Inc |year=1980 |url=http://www.strotmann.de/twiki/bin/view/Infothek/AtBasicReferenceMa |access-date=2020-04-14 |archive-date=2005-05-01 |archive-url=https://web.archive.org/web/20050501034651/http://www.strotmann.de/twiki/bin/view/Infothek/AtBasicReferenceMa |url-status=dead }} used the same concept, as did others.

Strings in Integer Basic used a fixed amount of memory regardless of the number of characters used within them, up to a maximum of 255 characters.{{sfn|Raskin|1978|p=89}} This had the advantage of avoiding the need for the garbage collection of the heap that was notoriously slow in MS BASIC{{efn|And completely broken in some versions.{{cite web |url=https://www.pagetable.com/?p=46 |title=Create your own Version of Microsoft BASIC}}}} but meant that strings that were shorter than the declared length was wasted.

Substring access was provided through array slicing syntax. For instance, {{code|PRINT A$(0,5)|basic}} printed the first six characters of {{code|A$}}, characters 0 through 5.{{sfn|Raskin|1978|p=88}}{{sfn|Raskin|1978|p=88}}{{efn|HP also allowed [ and ] in place of ( and ).}} Concatenation was provided using the same system, {{code|A$(5){{=}}"ABC"|basic}} replaced any characters starting at position 5 with the string "ABC".{{sfn|Raskin|1978|p=92}} This contrasts with the DEC/MS-style string handling which uses string functions like {{code|MID$}} to access substrings and {{code|+}} for concatenation.{{cite book |url=http://chiclassiccomp.org/docs/content/computing/MITS/MITS_Altair8800Basic4.1Reference_April1977.pdf |title=altair 8080 basic manual |date=April 1977 |publisher=MITS |page=30}}{{efn|It also contrasts with Dartmouth BASIC which used the {{code|CONVERT}} command to convert a string into an array of ASCII values which the user then manipulated and converted back to string format with a second {{code|CONVERT}}.}}

As many of the features that would be provided by string functions were instead provided by array slicing, the selection of string functions was reduced. {{code|LEN}} returned the length of a string{{sfn|Raskin|1978|p=89}} and {{code|ASC}} returned the ASCII numeric code for the first letter in a string.{{sfn|Raskin|1978|p=120}} It lacked an equivalent of the {{code|CHR$}} that returned the ASCII character with a given numeric code.{{sfn|Mini|1977|p=17}}

When launched, the only game controller for the Apple was the paddle controller, which had two controllers on a single connector. The position of the controller could be read using the {{code|PDL}} function, passing in the controller number, 0 or 1, like {{code|A{{=}}PDL(0):PRINT A|basic}}, returning a value between 0 and 255.{{sfn|Raskin|1978|p=36}}{{efn|The manual suggests, but does not outright state, that the actual range of values is less than 0 to 255.{{sfn|Raskin|1978|p=36}}}}

The Apple machines did not include dedicated sound hardware, only a simple "beeper". Producing sounds was accomplished by {{code|PEEK}}ing the memory-mapped location of the speaker, -16336.{{efn|The negative number is a side-effect of the integers being stored in signed format, so any memory location over 32767 appeared as a negative value in BASIC.{{sfn|Mini|1977|p=18}}}} Repeatedly PEEKing that value produced tones, and the manual suggested using a mathematical expression to do this, like {{code|S{{=}}PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)|basic}}.{{sfn|Raskin|1978|p=84}}

Support for graphics was more detailed. Graphics mode was turned on with the {{code|GR}} statement and off with {{code|TEXT}}.{{sfn|Raskin|1978|p=31}} Drawing was modal and normally started by issuing a command to change the color, which was accomplished by setting a pseudo-variable; {{code|COLOR{{=}}12}} would set the drawing color to 12, light green. One could then {{code|PLOT 10,10}} to produce a single spot of that color,{{sfn|Raskin|1978|p=32}} {{code|HLIN 0,39 AT 20}} to draw a horizontal line at row 20 that spanned the screen, or {{code|VLIN 5,15 AT 7}} to draw a shorter vertical line down column 7.{{sfn|Raskin|1978|p=33}} {{code|A{{=}}SCRN X,Y}} returned the color of the screen at X,Y.{{sfn|Raskin|1978|p=120}}{{efn|Note the odd syntax of the SCRN, which is technically a function because it returns a value, but does not use function-like syntax which would be {{code|A{{=}}SCRN(X,Y)}}.}}

Integer BASIC lacked any custom input/output commands, and also lacked the {{code|DATA}} statement and the associated {{code|READ}}. To get data into and out of a program, the input/output functionality was redirected to a selected card slot with the {{code|PR#x}} and {{code|IN#x}}, which redirected output or input (respectively) to the numbered slot. From then on, data could be sent to the card using conventional {{code|PRINT}} commands and read from it using {{code|INPUT}}.{{sfn|Raskin|1978|p=120}}

Integer BASIC included a {{code|TAB}} feature, which positioned the cursor on a given column from 0 to 39. It differed from the versions found in most BASICs in that it was a command with a following number, as opposed to a function with the value in parentheses; one would move the cursor to column 10 using {{code|TAB 10}} in Integer BASIC{{sfn|Raskin|1978|p=73}} whereas in MS this would be {{code|PRINT TAB(10)}}. Additionally, the {{code|VTAB}} command worked similar to {{code|TAB}} but added vertical spaces instead of horizontal. For unexplained reasons, in this case the coordinates were from 1 to 24 rather than 0 to 23.{{sfn|Raskin|1978|p=74}}

Integer BASIC included a {{code|POP}} command to exit from loops.{{sfn|Raskin|1978|p=120}} This popped the topmost item off the FOR stack. Atari BASIC also supported the same command,{{cite book |url=http://www.atarimania.com/documents/Atari-Basic-Reference-Manual-Rev-C.pdf |title=Atari BASIC Reference Manual |publisher=Atari |date=1983 |page=25}} while North Star BASIC used {{code|EXIT}}.{{cite book |title=North Star BASIC version 6 |url=http://itelsoft.com.au/north_star_manuals/North_Star_BASIC_Version_6.pdf |publisher=North Star Corporation |date=1977 |page=8 |access-date=2020-03-03 |archive-date=2020-03-05 |archive-url=https://web.archive.org/web/20200305045335/https://itelsoft.com.au/north_star_manuals/North_Star_BASIC_Version_6.pdf |url-status=dead }}

The Integer BASIC ROMs also included a machine code monitor, "mini-assembler", and disassembler to create and debug assembly language programs. Wozniak hand-assembled the monitor as the Apple II's first program, then used it to write Integer BASIC.{{sfn|Wozniak|1977|p=42}}{{sfn|Helmers|1978|p=18}}{{sfn|Weyhrich|2001}}

Apple BASIC had the following commands:{{cite web|url=https://archive.org/details/applei_basicman|title=PRELIMINARY APPLE BASIC USERS MANUAL|date=October 1976 }}

AUTO val1, val2

CLR [CLEAR]

DEL val1, val2

LIST val1, val2

RUN val1

SCR [SCRATCH / NEW]

HIMEM = expr

LOMEM = expr

(LET) var = expr

INPUT (prompt,) var1, var2 ...

PRINT item(s)

TAB expr

FOR var = expr1 TO expr2 STEP expr3

NEXT var

IF expr THEN statement

IF expr THEN line number

GOTO expr

GOSUB expr

RETURN

DIM var1(expr1), var2(expr2) ...

REM text

END

POKE expr1, expr2

CALL expr

Functions: ABS(), SGN(), PEEK(), RND(), LEN()

Integer BASIC added the following:{{cite web|url=https://archive.org/details/apple-ii-basic-programming/page/n1/mode/2up|title=APPLE II BASIC PROGRAMMING MANUAL|year=1978 }}{{cite web|url=http://www.classiccmp.org/cini/pdf/Apple/Apple%20II%20Reference%20Manual%20-%20Woz.pdf|title=APPLE II REFERENCE MANUAL}}

COLOR = expr

CON [CONTINUE]

DSP

GR

HLIN expr1, expr2 AT expr3

MAN

NEW [replaces SCR]

NOTRACE

PLOT expr1, expr2

POP

TEXT

TRACE

VLIN expr1, expr2 AT expr3

Function: ASC(), PDL(), SCRN(X,Y)

Integer BASIC read the lines typed in by the user from a buffer and ran them through a parser which output a series of tokens. As part of this process, simple syntax errors were detected and listed. If the parsing was successful, the line number (if present) was converted from ASCII decimal format into a 16-bit integer and any keywords into a 7-bit integer token.{{sfn|Wozniak|1977|p=42}}

Some keywords were represented by multiple tokens; for instance, where Microsoft BASIC had one token for the keyword {{code|PRINT}}, Integer BASIC had three tokens: one if the keyword was followed by no arguments, one if followed by an arithmetic expression, and one if followed by a string literal.{{cite web |url=https://www.callapple.org/docs/ap2/special/integerbasic.pdf |title=Apple II Integer Basic Disassembly |author=Paul R. Santa-Maria |access-date=2020-09-14 }}{{Dead link|date=March 2022 |bot=InternetArchiveBot |fix-attempted=yes }}

Numeric literals, like the value 500, were converted into their 16-bit (two-byte) binary representation, in this case, {{mono|$01F4}} hexadecimal. To indicate this was a value and not a keyword, a single byte between {{mono|$B0}} and {{mono|$B9}} was inserted in front of the two-byte value.{{efn|The first digit of the original value was used to select a value from 0 to 9, so in this example, the token would be {{mono|$B5}} for the first digit of 500.}} String literals, like "HELLO WORLD" were instead converted by setting the high bit of each character so that {{code|A}} was stored as {{mono|$C1}}. Variable names were converted in the same fashion, with the letters converted to have their high-bit turned on, and any digits in the name represented by the corresponding {{mono|$B0}} through {{mono|$B9}}, so that the variable {{code|A5}} would be tokenized as {{mono|$C1B5}}.{{sfn|Wozniak|1977|p=42}}

If the line was entered without a line number, the code was then executed directly from the buffer. If it had a line number, it was copied from the buffer into the program storage area.{{sfn|Wozniak|1977|p=42}}

The runtime interpreter used two stacks for execution: one for statement keywords and the other for evaluating the parameters. Each statement was given two priorities: one that stated where it should occur in a multi-step operation, like a string of mathematical operations to provide order of operations, and another that suggested when evaluation should occur, for instance, calculating internal values of a parentheses formula. When variables were encountered, their name was parsed and then looked up in the variable storage area. If it was not found, it was added to the end of the list. The address of the variable's storage, perhaps freshly created, was then placed on the evaluation stack.{{sfn|Wozniak|1977|p=42}}

{{Main|SWEET16}}

In addition to Integer BASIC, the Apple ROMs contained a custom assembler language known as SWEET16. SWEET16 is based on bytecodes that run within a simple 16-bit virtual machine. This model was used so memory could be addressed via indirect 16-bit pointers and 16-bit math functions calculated without the need to translate those to the underlying multi-instruction 8-bit 6502 code. The entire virtual machine was written in only 300 bytes. Code can call SWEET16 by issuing a subroutine call, and then return to normal 6502 code when the 16-bit operations are complete.{{sfn|Wozniak|1977|p=43}}

SWEET16 was not used by the core BASIC code, but was later used to implement several utilities. Notable among these was the line renumbering routine, which was included in the Programmer's Aid #1 ROM, added to later Apple II models and available for user installation on earlier examples.{{cite book |title=Apple Programmers Aid |publisher=Apple |date=1978 |url=http://www.classiccmp.org/cini/pdf/Apple/Apple%20Programmers%20Aid%20Book.pdf}}

Although Integer BASIC contained its own math routines, the Apple II ROMs also included a complete floating-point library located in ROM memory between {{code|$F425-$F4FB}} and {{code|$F63D-$F65D}}. The source code was included in the Apple II manual. BASIC programs requiring floating-point calculations could CALL into these routines.{{cite book |title=Apple II Reference Manual |date=January 1978 |url=http://www.classiccmp.org/cini/pdf/Apple/Apple%20II%20(Redbook)%20Reference%20Manual%2030th%20Anniversary.pdf |pages=94–95}}

Because Integer BASIC processed more of the original source code into tokens, the runtime was faster than versions that required additional runtime parsing. For comparison, Tiny BASIC tokenized only the line number,{{cite magazine |title=Build Your Own BASIC |first=Dennis |last=Allison |magazine=Dr. Dobb's Journal |volume=1 |number=1 |date=1976 |url=https://archive.org/details/dr_dobbs_journal_vol_01/page/n11 |page=11}} while MS BASICs tokenized only the keywords. So for instance, while Integer BASIC would convert the line {{code|100 GOTO 200}} entirely into tokens that could be immediately read and performed, in MS BASIC only the line number and GOTO would be tokenized, the "200" was left in its original ASCII format and had to be re-parsed into a 16-bit integer every time the line was encountered.{{cite web |url=http://www.rjh.org.uk/altair/4k/int_dis_11.htm |archive-url=https://web.archive.org/web/20011105014524/http://www.rjh.org.uk/altair/4k/int_dis_11.htm |archive-date=5 November 2001 |title=Altair BASIC 3.2 (4K) - Annotated Disassembly |first=Roger |last=Hardiman |page=1.11}}

Additionally, working solely with integer math provides another major boost in speed. This is due both to the smaller 16-bit format requiring fewer memory accesses, as well as removing the need to move the floating-point decimal after calculations. As many computer benchmarks of the era were small and often performed simple math that did not require floating-point, Integer BASIC trounced most other BASICs.{{efn|Bill Gates complained about this, stating that it was unfair to compare Integer BASIC to a "real" BASIC like MS.{{cite magazine |first1=Tom |last1=Rugg |first2=Phil |last2=Feldman |title=BASIC timing comparisons… revised and updated |magazine=Kilobaud |date=October 1977 |pages=20–25 |url=https://archive.org/details/kilobaudmagazine-1977-10}}}}

On one of the earliest known microcomputer benchmarks, the Rugg/Feldman benchmarks, Integer BASIC was well over twice as fast as Applesoft BASIC on the same machine.{{cite magazine |first1=Tom |last1=Rugg |first2=Phil |last2=Feldman |title=BASIC Timing Comparisons… information for speed freaks |magazine=Kilobaud |date=June 1977 |pages=66–70 |url=https://archive.org/details/kilobaudmagazine-1977-06}} In the Byte Sieve, where math was less important but array access and looping performance dominated, Integer BASIC took 166 seconds while Applesoft took 200.{{cite magazine |title=A High-Level Language Benchmark |first=Jim |last=Gilbreath |magazine=Byte |date=September 1981 |url=https://archive.org/details/byte-magazine-1981-09/page/n181 |page=192}} A review of Galfo Systems' Integer BASIC Compiler found that it produced code that is about 1.5 to eight times faster than compiled Applesoft BASIC, ten times faster than interpreted Integer BASIC, and 15 times faster than interpreted Applesoft.{{Cite magazine |last=Taylor |first=Joseph H. |last2=Taylor |first2=Jeffrey S. |date=September 1982 |title=A Comparison of Five Compilers for Applesoft BASIC |url=https://archive.org/details/byte-magazine-1982-09/page/n438/mode/1up?view=theater |access-date=2024-12-30 |magazine=BYTE |pages=440-464}} Integer BASIC did not appear in the Creative Computing Benchmark, which was first published in 1983, by which time the language was no longer included with Apple computers.{{cite magazine |magazine=Creative Computing |date=November 1983 |first=David |last=Ahl |title=Benchmark Comparison Test |url=https://archive.org/details/creativecomputing-1983-11/page/n271/mode/2up |page=260}}

The following test series, taken from both of the original Rugg/Feldman articles, show Integer's performance relative to the MS-derived BASIC on the same platform.

Here is a summary of what each test did:

• Test 1: for/next loop to 1000.
• Test 2: loop with compare to 1000.
• Test 3: same as 2 with added multiplication, division, addition subtraction by same variable.
• Test 4: same as 3 with added multiplication, division, addition subtraction by constants.
• Test 5: same as 4 with added subroutine call.
• Test 6; same as 5 with added inner loop.
• Test 7: same as 6 with added table population.

The following is a version of Breakout written in the 1977 version of Integer BASIC for the Apple II, which was listed in the Apple II Mini Manual.{{sfn|Mini|1977|pp=65-67}} There are a number of known bugs in this version.{{cite web|title=Breakout, Annotated|url=https://github.com/cmosher01/Apple-II-Source/blob/master/docs/breakout.md|website=GitHub|date=16 August 2021}}

The program starts by setting the display to {{code|TEXT}} and then {{code|CALL -936}} to clear the screen. Lines 20 through 27, and the associated subroutines at line 100 and 200, are the color selection code Wozniak demonstrated for Jobs. Line 30 sets up the text window with {{code|POKE 32,20}}{{efn|Meaning the text starts at line 20 of 24 lines on the screen, leaving four lines of text at the bottom.}} and then uses a series of {{code|COLOR}} and {{code|VLIN}} statements to draw the playfield and the score display in the text window. The entire main loop runs from line 40 through 90 with associated subroutines. Another large amount of code near the end of the program is concerned with printing the final score. Other notes of interest include the {{code|#}} (not-equal) comparisons on line 20, the production of a high-pitch sound using a string of {{code|PEEK}}s on line 65 compared to a lower-pitched tone using a loop on line 70, and the mix of graphics and text on a single display.{{efn|For a list of the various CALLs, PEEKs and POKEs that performed common operations on the Apple II, see [https://mirrors.apple2.org.za/ground.icaen.uiowa.edu/Collections/1WSW/MEGA.PEEKS.AND.POKES.html Peeks, Pokes, Calls And Programming Notes], Charles Turley, 15 December 1996.}}

5 TEXT: CALL -936: VTAB 4: TAB 10: PRINT "*** BREAKOUT GAME ***": PRINT

7 PRINT " OBJECT IS TO DESTROY ALL BRICKS WITH 5 BALLS": FOR N=1 TO 7000: NEXT N

10 DIM A$(20),B$(20): GR: PRINT: INPUT "HI, WHAT'S YOUR NAME? ",A$:A=1:B=13:C=9:D=6:E=15: PRINT "STANDARD COLORS,"; A$;

20 INPUT "? ",B$: IF B$#"N" AND B$#"NO" THEN 30: FOR I=0 TO 39: COLOR=I/2*(I<32): VLIN 0,39 AT I

25 NEXT I: POKE 34,20: PRINT: PRINT: PRINT: FOR I=0 TO 15: VTAB 21+I MOD 2: TAB I+I+1: PRINT I;: NEXT I: POKE 34,22: VTAB 24: PRINT: PRINT "BACKGROUND";

27 GOSUB 100: A=E: PRINT "EVEN BRICK";: GOSUB 100: B=E: PRINT "ODD BRICK";: GOSUB 100: C=E: PRINT "PADDLE";: GOSUB 100: D=E : PRINT "BALL";: GOSUB 100

30 POKE34,20:COLOR=A:FORI=0TO39:VLIN0,39ATI:NEXTI:FOR I=20TO34STEP2:TAB I+1:PRINT I/2-9;:COLOR=B:VLIN 0,39 AT I:COLOR=C:FOR J=I MOD 4 TO 39 STEP4

35 VLIN J,J+1 AT I: NEXT J,I: TAB 5: PRINT "SCORE = 0": PRINT: PRINT: POKE 34,21: S=0: P=S: L=S: X=19: Y=19: X=19

40 COLOR=A:PLOTX,Y/3:X=19:Y=RND(120):V=-1:W=RND(5)-2:L=L+1:IFL>5THEN140:TAB6:PRINT"BALL #";L:PRINT:FORI=1TO100:GOSUB200:NEXTI:M=1:N=0

50 J=Y+W: IF J>=0 AND J<120 THEN 60: W=-W: J=Y: FOR I=1 TO 6: K=PEEK(-16336): NEXT I

55 IF PEEK(-16287)>127 THEN SW=1-SW

60 I=X+V: IF I<0 THEN 400: GOSUB 200: COLOR=A: K=J/3: IF I>39 THEN 70: IF SCRN(I,K)=A THEN 90: IF I THEN 120: N=N+1: V=(N>9)+1: W=(K-P)*2-5:M=1

65 Z = PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336): GOTO 90

70 FOR I=1 TO 6: M=PEEK(-16336): NEXT I: I=X: M=0

80 V=-V

90 PLOT X,Y/3: COLOR=E: PLOT I,K: X=I: Y=J: GOTO 50

99 PRINT "INVALID. REENTER";

100 INPUT " COLOR (0 TO 15)",E: IF E<0 OR E>15 THEN 99: RETURN

120 IF M THEN V=ABS(V): VLIN K/2*2,K/2*2+1 AT I: S=S+I/2-9: VTAB 21: TAB 13: PRINT S

123 Q = PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)-PEEK(-16336)

124 IF S<720 THEN 80

130 PRINT "CONGRATULATIONS, YOU WIN.": GOTO 150

140 PRINT "YOUR SCORE OF ";S;" IS ";: GOTO 141+S/100

141 PRINT "TERRIBLE!": GOTO 150

142 PRINT "LOUSY.": GOTO 150

143 PRINT "POOR.": GOTO 150

144 PRINT "FAIR.": GOTO 150

145 PRINT "GOOD.": GOTO 150

146 PRINT "VERY GOOD.": GOTO 150

147 PRINT "EXCELLENT.": GOTO 150

148 PRINT "NEARLY PERFECT."

150 PRINT "SAME COLORS";: GOTO 20

200 IF SW THEN 220: Q=(PDL(0)-5)/6: IF Q<0 THEN Q=0

205 IF Q>=34 THEN Q=34: COLOR=D: VLIN Q,Q+5 AT 0: COLOR=A: IF P>Q THEN 210: IF Q THEN VLIN 0,Q-1 AT 0: P=Q: RETURN

210 IF P=Q THEN RETURN: IF Q#34 THEN VLIN Q+6,39 AT 0: P=Q: RETURN

220 Q=(Y-5)/3+RND(3)*SGN(W)*(X<10 AND V<0): IF Q<0 THEN Q=0: GOTO 205

400 FOR I=1 TO 80: Q=PEEK(-16336): NEXT I: GOTO 40

{{notelist}}

{{reflist}}

• {{cite book

|url=https://archive.org/details/Apple_II_Mini_Manual/

|title=Apple II Mini Manual

|publisher=Apple

|date=1977

|ref=CITEREFMini1977

}}

• {{cite web

|first=Andy |last=Hertzfeld

|title=The sad story of MacBasic

|url=https://www.folklore.org/StoryView.py?project=Macintosh&story=MacBasic.txt

|website=Folklore

|date=June 1985

}}

• {{cite magazine

|last=Helmers |first=Carl

|title=An Apple to Byte

|magazine=Byte

|date=March 1978

|pages=18–24, 30–32, 35, 40–46

|url=https://archive.org/stream/byte-magazine-1978-03/1978_03_BYTE_03-03_Computer_Music_Systems#page/n19/mode/2up

}}

• {{cite book

|first=Jef |last=Raskin

|title=Apple II BASIC Programming Manual

|publisher=Apple Computer

|date=1978

|url=http://www.classiccmp.org/cini/pdf/Apple/Apple%20II%20Basic%20Programming%20Manual.pdf

}}

• {{cite web

|first=Steven |last=Weyhrich

|title=History part 3: The Apple II

|date=12 December 2001

|url=http://apple2history.org/history/ah03/

|access-date=2007-09-16

}}

• {{cite magazine

|first=Steven |last=Wozniak

|title=System Description / The Apple-II

|magazine=Byte

|date=May 1977

|url=https://archive.org/stream/byte-magazine-1977-05/1977_05_BYTE_02-05_Interfacing#page/n35/mode/2up

|pages=34–43

}}

• {{cite magazine

|url=https://archive.org/stream/byte-magazine-1984-12/1984_12_BYTE_09-13_Communications#page/n461

|title=The Apple Story / Part 1: Early History

|magazine =Byte

|date=December 1984

|access-date=23 October 2013

|last1=Williams |first1=Gregg

|last2=Moore |first2=Rob

|pages=A67–A71

}}

• {{cite web

|first=Steven |last=Wozniak

|title=How Steve Wozniak Wrote BASIC for the Original Apple From Scratch

|website=Gizmodo

|url=https://gizmodo.com/how-steve-wozniak-wrote-basic-for-the-original-apple-fr-1570573636

|date=1 May 2014

}}

• {{cite web

|first=Steven |last=Wozniak

|title=Apple BASIC

|website=Woz.org

|date=3 January 2018

|url=http://woz.org/letters/apple-basic/

}}

• [https://6502disassembly.com/a2-rom/IntegerBASIC.html Apple II Integer Basic Disassembly], manually decompiled version by Paul Santa-Maria
• [http://www.landsnail.com/a2ref2.htm INTEGER BASIC Reference] – From Landsnail.com's "Apple II Programmer's Reference" website
• [http://apple1computer.blogspot.com/2010/05/apple-1-basic-firmware-card-it-works.html Apple-1 BASIC firmware card] designed by John Calande, schematic included

{{BASIC}}

{{Apple Inc.}}

Category:Apple II software

Category:BASIC interpreters

Category:Assembly language software

Category:BASIC programming language family